VALUES DAX Function (Table manipulation)
When a column name is given, returns a single-column table of unique values. When a table name is given, returns a table with the same columns and all the rows of the table (including duplicates) with the additional blank row caused by an invalid relationship if present.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
| TableNameOrColumnName |
A column name or a table name. |
Return values
A column of unique values if the parameter is a single column.
If the parameter is a table expression, the result has the same columns and does not remove duplicated rows.
Remarks
VALUES is similar to DISTINCT, but it can have an additional blank row in case the table has at least one one-to-many relationship with other tables where there is a violation of referential integrity.
» 1 related function
Examples
-- DISTINCT retrieves the distinct values of a column
-- VALUES does the same.
-- They differ in the way they handle the blank row generated
-- for invalid relationships, if present
-- DISTINCT does not return the blank row caused by an invalid relationship
-- VALUES includes the blank row caused by an invalid relationship, if present
EVALUATE
SUMMARIZECOLUMNS (
Store[Continent],
"#Stores (no blank row)", COUNTROWS ( DISTINCT ( Store[Store Name] ) ),
"#Stores (blank row)", COUNTROWS ( VALUES ( Store[Store Name] ) )
)
| Continent | #Stores (no blank row) | #Stores (blank row) |
|---|---|---|
| North America | 209 | 209 |
| Europe | 54 | 54 |
| Asia | 41 | 41 |
| (Blank) | (Blank) | 1 |
-- DISTINCT and VALUES can also be used with a table.
-- DISTINCT returns the distinct rows in the table.
-- VALUES returns the table, with the blank row caused
-- by an invalid relationship if it exists,
-- but without performing a distinct.
-- Worth remembering that a table reference does not return
-- the blank row caused by an invalid relationship if you
-- just use the table name.
EVALUATE
SUMMARIZECOLUMNS (
Store[Continent],
"#Stores", COUNTROWS ( Store ),
"#Stores (no blank row)", COUNTROWS ( DISTINCT ( Store ) ),
"#Stores (blank row)", COUNTROWS ( VALUES ( Store ) )
)
| Continent | #Stores | #Stores (no blank row) | #Stores (blank row) |
|---|---|---|---|
| North America | 209 | 209 | 209 |
| Europe | 54 | 54 | 54 |
| Asia | 41 | 41 | 41 |
| (Blank) | (Blank) | (Blank) | 1 |
-- DISTINCT can be used with variables.
-- VALUES requires a table or a column that exists in the model.
EVALUATE
VAR Stores =
SELECTCOLUMNS ( Store, "Continent", Store[Continent] )
RETURN
{
( "#Stores (all rows)", COUNTROWS ( ( Stores ) ) ),
( "#Stores (no blank row)", COUNTROWS ( DISTINCT ( Stores ) ) )
--
-- The following would produce an error: VALUES cannot be used with variables
--
-- ( "#Stores (blank row)", COUNTROWS ( VALUES ( Stores ) ) )
}
| Value1 | Value2 |
|---|---|
| #Stores (all rows) | 304 |
| #Stores (no blank row) | 3 |
Related articles
Learn more about VALUES in the following articles:
-
Physical and Virtual Relationships in DAX
DAX calculations can leverage relationships present in the data model, but you can obtain the same result without physical relationships, applying equivalent filters using specific DAX patterns. This article show a more efficient technique to apply virtual relationships in DAX… » Read more
-
Using ALLEXCEPT versus ALL and VALUES
This article describes the semantic difference between ALLEXCEPT and the joint use of ALL and VALUES, showing practical examples of the different results in Power BI and SSAS 2016. » Read more
-
Blank row in DAX
There are two functions in DAX that return the list of values of a column: VALUES and DISTINCT. This article describes the difference between the two, explaining the details of the blank row added to tables for invalid relationships. » Read more
-
Using SELECTEDVALUE with Fields Parameters in Power BI
If you try to use SELECTEDVALUE on the visible column of the table generated by the Fields Parameters feature in Power BI, you get the following error: Calculation error in measure ‘Sales'[Selection]: Column [Parameter] is part of composite key, but… » Read more
-
Understanding blank row and limited relationships
DAX creates a blank row to guarantee that results are accurate even if a regular relationship is invalid. The blank row is not created for limited relationships. This article shows the effect of not having a blank row in your tables. » Read more
-
Blank in date columns and DAX time intelligence functions
This article explores the implications of having blank values in date columns and provides the best practices for managing them in DAX calculations and Power BI reports. » Read more
-
Choosing between DISTINCT and VALUES in DAX
When should you use DISTINCT over VALUES in DAX? Here is how to write resilient measures that survive bad data and model changes. » Read more
Related functions
Other related functions are:
Last update: Jul 2, 2025 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo, Kenneth Barber
Microsoft documentation: https://docs.microsoft.com/en-us/dax/values-function-dax