SUMMARIZECOLUMNS DAX Function (Table manipulation)
Create a summary table for the requested totals over set of groups.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
| GroupBy_ColumnName | Optional Repeatable |
A column to group by or a call to ROLLUPGROUP function and ROLLUPADDISSUBTOTAL function to specify a list of columns to group by with subtotals. |
| FilterTable | Optional Repeatable |
An expression that defines the table from which rows are to be returned. |
| Name | Optional Repeatable |
A column name to be added. |
| Expression | Optional Repeatable |
The expression of the new column. |
Return values
A table which includes combinations of values from the supplied columns, based on the grouping specified. Only rows for which at least one of the supplied expressions return a non-blank value are included in the table returned. If all expressions evaluate to BLANK for a row, that row is not included in the table returned.
Remarks
SUMMARIZECOLUMNS does not support evaluation within a context transition. This makes it not useful in most of the measures – a measure with SUMMARIZECOLUMNS can be called also by CALCULATE but not in any case of context transition, including other SUMMARIZECOLUMNS statements. Client tools like Excel and Power BI almost always generate context transitions to evaluate measures in the reports.
SUMMARIZECOLUMNS always combines all the filters on the same table into a single filter. The combined table resulting from this filter only contains columns explicitly listed in SUMMARIZECOLUMNS as grouping columns or filter columns. This is the auto-exists behavior that has side effects on functions such as FILTERS.
Filters in SUMMARIZECOLUMNS only apply to group-by columns from the same table and to measures. They do not apply to group-by columns from other tables directly, but indirectly through the implied non-empty filter from measures. In order to apply a filter to the group-by column unconditionally, apply the filter through a CALCULATETABLE function that evaluates SUMMARIZECOLUMNS.
SUMMARIZECOLUMNS does not preserve the data lineage of the columns used in ROLLUPADDISSUBTOTAL or ROLLUPGROUP. If such columns are later used in the filter context, they are ignored. This behavior is different from SUMMARIZE, where the same situation raises an error.
» 7 related functions
Examples
-- SUMMARIZECOLUMNS is the primary querying function in DAX
-- It provides most querying features in a single function:
-- First set of arguments are the groupby columns
-- Second set are the filters
-- Third set are additional columns added to the resultset
EVALUATE
SUMMARIZECOLUMNS (
'Product'[Brand],
'Date'[Calendar Year],
TREATAS ( { "CY 2008", "CY 2009" }, 'Date'[Calendar Year] ),
TREATAS ( { "Red", "Blue" }, 'Product'[Color] ),
"Amount", [Sales Amount],
"Qty", SUM ( Sales[Quantity] )
)
| Brand | Calendar Year | Amount | Qty |
|---|---|---|---|
| Contoso | 2008-01-01 | 449,704.15 | 1,851 |
| Wide World Importers | 2008-01-01 | 87,108.20 | 213 |
| Northwind Traders | 2008-01-01 | 152,389.53 | 263 |
| Adventure Works | 2008-01-01 | 74,735.98 | 230 |
| Southridge Video | 2008-01-01 | 9,902.09 | 688 |
| Litware | 2008-01-01 | 244,134.07 | 611 |
| Fabrikam | 2008-01-01 | 274,937.21 | 557 |
| Proseware | 2008-01-01 | 50,642.52 | 178 |
| A. Datum | 2008-01-01 | 27,733.20 | 60 |
| Tailspin Toys | 2008-01-01 | 22,856.00 | 677 |
| Contoso | 2009-01-01 | 298,096.75 | 1,703 |
| Wide World Importers | 2009-01-01 | 75,496.96 | 312 |
| Northwind Traders | 2009-01-01 | 73,747.19 | 156 |
| Adventure Works | 2009-01-01 | 81,845.29 | 216 |
| Southridge Video | 2009-01-01 | 10,696.16 | 692 |
| Litware | 2009-01-01 | 184,703.58 | 756 |
| Fabrikam | 2009-01-01 | 222,621.82 | 506 |
| Proseware | 2009-01-01 | 71,255.37 | 371 |
| Tailspin Toys | 2009-01-01 | 51,084.87 | 1,797 |
-- SUMMARIZECOLUMNS can compute subtotals as part of the query result
EVALUATE
SUMMARIZECOLUMNS (
ROLLUPADDISSUBTOTAL ( 'Product'[Brand], "Brand total" ),
ROLLUPADDISSUBTOTAL ( 'Date'[Calendar Year], "Year total" ),
TREATAS ( { "CY 2008" }, 'Date'[Calendar Year] ),
TREATAS ( { "Contoso", "Litware" }, 'Product'[Brand] ),
"Amount", [Sales Amount],
"Qty", SUM ( Sales[Quantity] )
)
ORDER BY [Year Total] ASC, [Calendar Year], [Brand Total] ASC, [Brand]
| Brand | Calendar Year | Brand total | Year total | Amount | Qty |
|---|---|---|---|---|---|
| Contoso | 2008-01-01 | false | false | 2,369,167.68 | 14,901 |
| Litware | 2008-01-01 | false | false | 1,487,846.74 | 3,364 |
| (Blank) | 2008-01-01 | true | false | 3,857,014.43 | 18,265 |
| Contoso | (Blank) | false | true | 2,369,167.68 | 14,901 |
| Litware | (Blank) | false | true | 1,487,846.74 | 3,364 |
| (Blank) | (Blank) | true | true | 3,857,014.43 | 18,265 |
-- Blank values are automatically removed from the output,
-- unless you use the IGNORE modifier for newly introduced
-- columns.
-- Removed rows can also be reintroduced later by using ADDMISSINGITEMS
EVALUATE
SUMMARIZECOLUMNS (
'Date'[Calendar Year],
"Amount", [Sales Amount]
)
EVALUATE
ADDMISSINGITEMS (
'Date'[Calendar Year],
SUMMARIZECOLUMNS (
'Date'[Calendar Year],
"Amount", [Sales Amount]
),
'Date'[Calendar Year]
)
ORDER BY 'Date'[Calendar Year]
| Calendar Year | Amount |
|---|---|
| 2007-01-01 | 11,309,946.12 |
| 2008-01-01 | 9,927,582.99 |
| 2009-01-01 | 9,353,814.87 |
| Calendar Year | Amount |
|---|---|
| 2005-01-01 | (Blank) |
| 2006-01-01 | (Blank) |
| 2007-01-01 | 11,309,946.12 |
| 2008-01-01 | 9,927,582.99 |
| 2009-01-01 | 9,353,814.87 |
| 2010-01-01 | (Blank) |
| 2011-01-01 | (Blank) |
SUMMARIZECOLUMNS cannot be used if the filter context contains a row context or a filter context generated by context transition or an arbitrarily shaped set. This limitation makes it unusable in any measure. It is a function intended solely for queries and calculated tables.
The following query produces an error:
EVALUATE
ADDCOLUMNS (
VALUES ( 'Date'[Calendar Year] ),
"Test",
SUMX (
SUMMARIZECOLUMNS (
'Product'[Brand],
"Qty", SUM ( Sales[Quantity] )
),
[Qty]
)
)
Related articles
Learn more about SUMMARIZECOLUMNS in the following articles:
-
Introducing SUMMARIZECOLUMNS
This article explains how to use SUMMARIZECOLUMNS, which is a replacement of SUMMARIZE and does not require the use of ADDCOLUMNS to obtain good performance. » Read more
-
Understanding DAX Auto-Exist
This article describes the behavior of auto-exist in DAX, explaining the side effects of combining slicers on columns of the same table in Power BI. » Read more
-
Naming temporary columns in DAX
This article describes a naming convention for temporary columns in DAX expressions to avoid ambiguity with the measure reference notation. » Read more
-
Implementing real-time updates in Power BI using push datasets instead of DirectQuery
Push datasets are an efficient and inexpensive way to implement real-time updates in Power BI reports and dashboards. They can provide better performance and scalability than DirectQuery at the price of a small development cost. » Read more
Related functions
Other related functions are:
Last update: May 24, 2022 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo, Bill Neil, Colin Maitland
Microsoft documentation: https://docs.microsoft.com/en-us/dax/summarizecolumns-function-dax