DEFINE
    VAR Vals = GENERATESERIES ( -5, 5 )
EVALUATE
    ADDCOLUMNS (
        Vals,
        "BITLSHIFT 1", BITLSHIFT ( [Value], 1 ),
        "BITLSHIFT 2", BITLSHIFT ( [Value], 2 ),
        "BITLSHIFT 3", BITLSHIFT ( [Value], 3 ),
        "BITRSHIFT 1", BITRSHIFT ( [Value], 1 ),
        "BITRSHIFT 2", BITRSHIFT ( [Value], 2 ),
        "BITRSHIFT 3", BITRSHIFT ( [Value], 3 )
    )

// This longer code produces an easier to read output 
// by showing the result in both decimal and binary formats
//
// Contribution by Kenneth Barber
DEFINE
    VAR MinimumNumber = -5
    VAR MaximumNumber = 5
    VAR MinimumShiftAmount = -3
    VAR MaximumShiftAmount = 3
    TABLE 'Numbers' =
        VAR NumberOfBitsToShow =
            //This excludes the sign bit before the "…"
            ROUNDUP (
                LOG ( MAX ( ABS ( MinimumNumber ), ABS ( MaximumNumber ) ) + 1, 2 )
                    + MAX ( ABS ( MinimumShiftAmount ), ABS ( MaximumShiftAmount ) ),
                0
            )
        RETURN
            ADDCOLUMNS (
                VAR Limit =
                    BITLSHIFT ( 1, NumberOfBitsToShow )
                RETURN
                    GENERATESERIES ( - Limit, Limit - 1 ),
                //We precompute the binary representations of all possible values
                //so that we can simply look them up later
                "Value (Binary)",
                    VAR Number = [Value]
                    RETURN
                        INT ( Number < 0 ) & "…"
                            & CONCATENATEX (
                                ADDCOLUMNS (
                                    GENERATESERIES ( 0, NumberOfBitsToShow ),
                                    "Bit", MOD ( BITRSHIFT ( Number, [Value] ), 2 )
                                ),
                                [Bit],
                                "",
                                [Value], DESC
                            )
            )

EVALUATE
GENERATE (
    CROSSJOIN (
        SELECTCOLUMNS (
            CALCULATETABLE (
                'Numbers',
                'Numbers'[Value] >= MinimumNumber,
                'Numbers'[Value] <= MaximumNumber
            ),
            "Number", [Value],
            "Number (Binary)", [Value (Binary)]
        ),
        SELECTCOLUMNS (
            GENERATESERIES ( MinimumShiftAmount, MaximumShiftAmount ),
            "Shift Amount", [Value]
        )
    ),
    VAR BITLSHIFTresult =
        BITLSHIFT ( [Number], [Shift Amount] )
    VAR BITRSHIFTresult =
        BITRSHIFT ( [Number], [Shift Amount] )
    RETURN
        ROW (
            "BITLSHIFT", BITLSHIFTresult,
            "BITLSHIFT (Binary)", LOOKUPVALUE ( 'Numbers'[Value (Binary)], 'Numbers'[Value], BITLSHIFTresult ),
            "BITRSHIFT", BITRSHIFTresult,
            "BITRSHIFT (Binary)", LOOKUPVALUE ( 'Numbers'[Value (Binary)], 'Numbers'[Value], BITRSHIFTresult )
        )
)
ORDER BY
    [Number] DESC,
    [Shift Amount] DESC