--  DISTINCT retrieves the distinct values of a column
--  VALUES does the same.
--  They differ in the way they handle the blank row generated
--  for invalid relationships, if present
--  DISTINCT does not return the blank row caused by an invalid relationship 
--  VALUES includes the blank row caused by an invalid relationship, if present
EVALUATE
SUMMARIZECOLUMNS (
    Store[Continent],
    "#Stores (no blank row)", COUNTROWS ( DISTINCT ( Store[Store Name] ) ),
    "#Stores (blank row)",    COUNTROWS ( VALUES ( Store[Store Name] ) )
)

--  DISTINCT and VALUES can also be used with a table.
--  DISTINCT returns the distinct rows in the table.
--  VALUES returns the table, with the blank row caused 
--  by an invalid relationship if it exists,
--  but without performing a distinct.
--  Worth remembering that a table reference does not return
--  the blank row caused by an invalid relationship if you 
--  just use the table name.
EVALUATE
SUMMARIZECOLUMNS (
    Store[Continent],
    "#Stores",                COUNTROWS ( Store ),
    "#Stores (no blank row)", COUNTROWS ( DISTINCT ( Store ) ),
    "#Stores (blank row)",    COUNTROWS ( VALUES ( Store ) )
)

--  DISTINCT can be used with variables.
--  VALUES requires a table or a column that exists in the model.
EVALUATE
VAR Stores = 
    SELECTCOLUMNS ( Store, "Continent", Store[Continent] )
RETURN
    {
        ( "#Stores (all rows)",     COUNTROWS (          ( Stores ) ) ),
        ( "#Stores (no blank row)", COUNTROWS ( DISTINCT ( Stores ) ) )
        --
        --  The following would produce an error: VALUES cannot be used with variables
        --
        -- ( "#Stores (blank row)",    COUNTROWS ( VALUES ( Stores ) ) )
    }