--  ROLLUPADDISSUBTOTAL computes subtotals for the specified
--  columns and adds a new column to the result indicating 
--  whether the current row is a subtotal or not.
EVALUATE
SUMMARIZECOLUMNS (
    ROLLUPADDISSUBTOTAL ( 'Date'[Calendar Year], "Year total" ),
    TREATAS ( { "CY 2008", "CY 2009" }, 'Date'[Calendar Year] ),
    TREATAS ( { "Bachelors", "Partial College" }, Customer[Education] ),
    "Amount", [Sales Amount]
)
ORDER BY [Year total], [Calendar Year]

--  You can specify multiple ROLLUPADDISSUBTOTAL in the same query
--  to produce matrices of subtotals.
EVALUATE
SUMMARIZECOLUMNS (
    ROLLUPADDISSUBTOTAL ( 'Date'[Calendar Year], "Year total" ),
    ROLLUPADDISSUBTOTAL ( Customer[Education],   "Education total" ),
    TREATAS ( { "CY 2008", "CY 2009" }, 'Date'[Calendar Year] ),
    TREATAS ( { "Bachelors", "Partial College" }, Customer[Education] ),
    "Amount", [Sales Amount]
)
ORDER BY [Year total], [Calendar Year], [Education total], [Education]

--  Alternatively, you can use multiple ROLLUP columns in the same
--  ROLLUPADDISSUBTOTAL to reduce the number of subtotals generated
--  including only the group totals at higher levels following the 
--  hierarchy of columns specified.

-- The first result has subtotals by Year and then Education (no Education total)
EVALUATE
SUMMARIZECOLUMNS (
    ROLLUPADDISSUBTOTAL ( 
        'Date'[Calendar Year], "Year total",
        Customer[Education],   "Education total" 
    ),
    TREATAS ( { "CY 2008", "CY 2009" }, 'Date'[Calendar Year] ),
    TREATAS ( { "Bachelors", "Partial College" }, Customer[Education] ),
    "Amount", [Sales Amount]
)
ORDER BY [Year total], [Calendar Year], [Education total], [Education]

-- The second result has subtotals by Education and then Year (no Year total)
EVALUATE
SUMMARIZECOLUMNS (
    ROLLUPADDISSUBTOTAL ( 
        Customer[Education],   "Education total",
        'Date'[Calendar Year], "Year total"
    ),
    TREATAS ( { "CY 2008", "CY 2009" }, 'Date'[Calendar Year] ),
    TREATAS ( { "Bachelors", "Partial College" }, Customer[Education] ),
    "Amount", [Sales Amount]
)
ORDER BY [Year total], [Education], [Calendar Year]

--  Using ROLLUPGROUP you can further reduce the number of subtotals
--  by grouping together several columns.
EVALUATE
SUMMARIZECOLUMNS (
    ROLLUPADDISSUBTOTAL (
        ROLLUPGROUP ( 'Date'[Calendar Year], Customer[Education] ),
        "Year total"
    ),
    TREATAS ( { "CY 2008", "CY 2009" }, 'Date'[Calendar Year] ),
    TREATAS ( { "Bachelors", "Partial College" }, Customer[Education] ),
    "Amount", [Sales Amount]
)
ORDER BY
    [Year total],
    [Calendar Year],
    [Education]