PREVIOUSQUARTER DAX Function (Time Intelligence) Context Transition
Returns a previous quarter.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
| Dates |
The name of a column containing dates or a one column table containing dates. |
Return values
A table containing a single column of date values.
Notes
In order to use any time intelligence calculation, you need a well-formed date table. The Date table must satisfy the following requirements:
- All dates need to be present for the years required. The Date table must always start on January 1 and end on December 31, including all the days in this range. If the report only references fiscal years, then the date table must include all the dates from the first to the last day of a fiscal year. For example, if the fiscal year 2008 starts on July 1, 2007, then the Date table must include all the days from July 1, 2007 to June 30, 2008.
- There needs to be a column with a DateTime or Date data type containing unique values. This column is usually called Date. Even though the Date column is often used to define relationships with other tables, this is not required. Still, the Date column must contain unique values and should be referenced by the Mark as Date Table feature. In case the column also contains a time part, no time should be used – for example, the time should always be 12:00 am.
- The Date table must be marked as a date table in the model, in case the relationship between the Date table and any other table is not based on the Date.
Remarks
The result includes all the days in the previous quarter considering the first day in the dates argument.
The dates argument can be any of the following:
- A reference to a date/time column. Only in this case a context transition applies because the column reference is replaced by
- CALCULATETABLE ( DISTINCT ( <Dates> ) )
- A table expression that returns a single column of date/time values.
- A Boolean expression that defines a single-column table of date/time values.
The result table includes only dates that exist in the dates column.
Internally, PREVIOUSQUARTER corresponds to the following call of PARALLELPERIOD:
PARALLELPERIOD ( FIRSTDATE ( <Dates> ), -1, QUARTER )
» 7 related functions
Examples
-- PREVIOUSQUARTER returns the full quarter before the first day in the selection
EVALUATE
CALCULATETABLE (
PREVIOUSQUARTER ( 'Date'[Date] ),
'Date'[Date] >= DATE ( 2008, 08, 15 ) &&
'Date'[Date] <= DATE ( 2008, 08, 20 )
)
ORDER BY [Date] ASC
| Date |
|---|
| 2008-04-01 |
| 2008-04-02 |
| … |
| 2008-06-29 |
| 2008-06-30 |
-- All time intelligence function are designed to return a table
-- to be easily used in CALCULATE as a filter.
EVALUATE
VAR StartDate = DATE ( 2008, 08, 15 )
VAR EndDate = DATE ( 2008, 08, 20 )
RETURN
CALCULATETABLE (
ROW (
"Selection",
[Sales Amount],
"Previous Quarter",
CALCULATE (
[Sales Amount],
PREVIOUSQUARTER ( 'Date'[Date] ) -- 2008-04-01 : 2008-06-30
)
),
'Date'[Date] >= StartDate
&& 'Date'[Date] <= EndDate
)
| Selection | Previous Quarter |
|---|---|
| 91,636.30 | 2,738,040.73 |
Related articles
Learn more about PREVIOUSQUARTER in the following articles:
-
Differences between DATEADD and PARALLELPERIOD in DAX
This article describes the difference between the results of DATEADD and PARALLELPERIOD in DAX. These differences also impact many other time intelligence functions that are syntax sugar of these two. » Read more
Related functions
Other related functions are:
Last update: Dec 14, 2024 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo
Microsoft documentation: https://docs.microsoft.com/en-us/dax/previousquarter-function-dax