PERCENTILEX.INC DAX Function (Statistical)
Returns the k-th (inclusive) percentile of an expression values in a table.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
|
Table Iterator |
Table over which the Expression will be evaluated. |
|
|
Expression Row Context |
Expression to evaluate for each row of the table. |
|
| K |
Desired percentile value in the interval [0,1]. |
Return values
Percentile value.
Remarks
PERCENTILEX.INC considers the blank values returned by Expression. This behavior is different from PERCENTILE.INC, which ignores the blank values.
» 3 related functions
Examples
-- PERCENTILEX iterates the table and compute the expression for each row,
-- computing the k-th percentile
EVALUATE
{
( "Average Sales", AVERAGEX ( Sales, Sales[Quantity] * Sales[Net Price] ) ),
( "Median Sales", MEDIANX ( Sales, Sales[Quantity] * Sales[Net Price] ) ),
( "Percentile Sales 0.25", PERCENTILEX.INC ( Sales, Sales[Quantity] * Sales[Net Price], 0.25 ) ),
( "Percentile Sales 0.50", PERCENTILEX.INC ( Sales, Sales[Quantity] * Sales[Net Price], 0.50 ) ),
( "Percentile Sales 0.75", PERCENTILEX.INC ( Sales, Sales[Quantity] * Sales[Net Price], 0.75 ) )
}
| Value1 | Value2 |
|---|---|
| Average Sales | 305.21 |
| Median Sales | 114.21 |
| Percentile Sales 0.25 | 22.99 |
| Percentile Sales 0.50 | 114.21 |
| Percentile Sales 0.75 | 345.60 |
--
-- Different handling of blanks between PERCENTILE and PERCENTILEX
-- PERCENTILE ignores blank values
-- PERCENTILEX considers blank values
--
-- MEDIANX corresponds to PERCENTILEX.INC with k=0.50
DEFINE
TABLE SampleDataWithBlanks =
{ BLANK (), BLANK (), BLANK (), 1, 2, 3, 4 }
EVALUATE
{
( "PERCENTILE.INC 0.25", PERCENTILE.INC ( SampleDataWithBlanks[Value], 0.25 ) ),
( "PERCENTILE.INC 0.50", PERCENTILE.INC ( SampleDataWithBlanks[Value], 0.50 ) ),
( "PERCENTILE.INC 0.75", PERCENTILE.INC ( SampleDataWithBlanks[Value], 0.75 ) ),
( "PERCENTILEX.INC 0.25", PERCENTILEX.INC ( SampleDataWithBlanks, SampleDataWithBlanks[Value], 0.25 ) ),
( "PERCENTILEX.INC 0.50", PERCENTILEX.INC ( SampleDataWithBlanks, SampleDataWithBlanks[Value], 0.50 ) ),
( "PERCENTILEX.INC 0.75", PERCENTILEX.INC ( SampleDataWithBlanks, SampleDataWithBlanks[Value], 0.75 ) ),
( "MEDIANX", MEDIANX ( SampleDataWithBlanks, SampleDataWithBlanks[Value] ) )
}
| Value1 | Value2 |
|---|---|
| PERCENTILE.INC 0.25 | 1.75 |
| PERCENTILE.INC 0.50 | 2.5 |
| PERCENTILE.INC 0.75 | 3.25 |
| PERCENTILEX.INC 0.25 | (Blank) |
| PERCENTILEX.INC 0.50 | 1 |
| PERCENTILEX.INC 0.75 | 2.5 |
| MEDIANX | 1 |
Related articles
Learn more about PERCENTILEX.INC in the following articles:
-
Statistical Patterns
DAX includes a few statistical aggregation functions, such as average, variance, and standard deviation. Other typical statistical calculations require you to write longer DAX expressions. Excel, from this point of view, has a much richer language. The Statistical Patterns are a collection of common statistical calculations: median, mode, moving average, percentile, and quartile. » Read more
Related functions
Other related functions are:
Last update: Nov 14, 2024 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo, Ville-Pietari Louhiala, Kenneth Barber
Microsoft documentation: https://docs.microsoft.com/en-us/dax/percentilex-inc-function-dax