--  NORM.INV returns the inverse of the normal distribution 
--  for the specified mean and standard deviation
--
--  NORM.S.INV returns the inverse of the standard normal distribution 
--  (has a mean of zero and a standar deviation of one)
--
--  https://en.wikipedia.org/wiki/Normal_distribution
DEFINE
    TABLE SampleData    = { 2, 4, 4, 4, 5, 5, 7, 9 }
    VAR Mean            = AVERAGE ( SampleData[Value] )
    VAR StandardDev     = STDEV.S ( SampleData[Value] )
    VAR Percs           = GENERATESERIES ( 0.05, 0.99, 0.05 )
    VAR CumulativeTrue  = TRUE   -- Cumulative distribution function
    VAR CumulativeFalse = FALSE  -- Probability density function
EVALUATE
SELECTCOLUMNS (
    Percs,
    "Probability %", [Value],
    "Inv. Normal Distr.",          -- Probability density function
        FORMAT (
            NORM.INV ( [Value], Mean, StandardDev ),
            "#,0.00000"
        ),
    "Inv. Standard Normal Distr.", -- Probability density function
        FORMAT (
            NORM.S.INV ( [Value] ),
            "#,0.00000"
        )
)

--  Example of how to use NORM.INV with RAND to generate Gaussian 
--  (normally distributed) random samples
DEFINE
    -- Mean
    VAR mu = 10 
    -- Standard deviation
    VAR sigma = 3 
    -- Amount of samples
    VAR N = 1000
    -- Table containing normally distributed random samples with the given parameters
    TABLE RawData =
        ADDCOLUMNS (
            GENERATESERIES ( 1, N ),
            "Random data", ROUND ( NORM.INV ( RAND (), mu, sigma ), 0 )
        )
    -- Table containing the "bins" which are used to summarize the random data
    TABLE SummaryTable =
        GENERATESERIES ( 1, 20 )

EVALUATE
ADDCOLUMNS (
    SummaryTable,
    "Count of occurrences",
        -- Caculate the amount of samples per category of the summarize table
        CALCULATE (
            COUNTROWS ( RawData ),
            FILTER ( RawData, RawData[Random data] = SummaryTable[Value] )
        ),
    "Histogram",
        -- Form a visual histogram of the results
        CONCATENATEX (
            -- Form a temporary table for creating the histogram via string concatenation
            ADDCOLUMNS (
                FILTER ( RawData, RawData[Random data] = SummaryTable[Value] ),
                "|", "|"
            ),
            "|"
        )
)