LASTDATE DAX Function (Time Intelligence) Context Transition
Returns last non blank date.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
| Dates |
The name of a column containing dates or a one column table containing dates. |
Return values
Notes
In order to use any time intelligence calculation, you need a well-formed date table. The Date table must satisfy the following requirements:
- All dates need to be present for the years required. The Date table must always start on January 1 and end on December 31, including all the days in this range. If the report only references fiscal years, then the date table must include all the dates from the first to the last day of a fiscal year. For example, if the fiscal year 2008 starts on July 1, 2007, then the Date table must include all the days from July 1, 2007 to June 30, 2008.
- There needs to be a column with a DateTime or Date data type containing unique values. This column is usually called Date. Even though the Date column is often used to define relationships with other tables, this is not required. Still, the Date column must contain unique values and should be referenced by the Mark as Date Table feature. In case the column also contains a time part, no time should be used – for example, the time should always be 12:00 am.
- The Date table must be marked as a date table in the model, in case the relationship between the Date table and any other table is not based on the Date.
Remarks
The dates argument can be any of the following:
- A reference to a date/time column. Only in this case a context transition applies because the column reference is replaced by
- CALCULATETABLE ( DISTINCT ( <Dates> ) )
- A table expression that returns a single column of date/time values.
- A Boolean expression that defines a single-column table of date/time values.
The result table includes only dates that exist in the dates column.
The function MAX should be used instead of LASTDATE when the result must be a scalar value instead of a table.
» 3 related functions
Examples
-- FIRSTDATE returns the minimum date selected, as a table.
-- LASTDATE returns the maximum date, still packed into a table.
DEFINE
VAR StartDate = DATE ( 2008, 08, 15 )
VAR EndDate = DATE ( 2008, 08, 31 )
EVALUATE
CALCULATETABLE (
FIRSTDATE ( 'Date'[Date] ),
'Date'[Date] >= StartDate && 'Date'[Date] <= EndDate
)
EVALUATE
CALCULATETABLE (
LASTDATE ( 'Date'[Date] ),
'Date'[Date] >= StartDate && 'Date'[Date] <= EndDate
)
| Date |
|---|
| 2008-08-15 |
| Date |
|---|
| 2008-08-31 |
-- All time intelligence function are designed to return a table
-- to be easily used in CALCULATE as a filter.
DEFINE
VAR StartDate = DATE ( 2008, 01, 01 )
VAR EndDate = DATE ( 2008, 01, 31 )
EVALUATE
CALCULATETABLE (
{ (
CALCULATE (
[Sales Amount],
FIRSTDATE ( 'Date'[Date] ) -- 2008-01-01
),
CALCULATE (
[Sales Amount],
LASTDATE ( 'Date'[Date] ) -- 2008-01-31
)
) },
'Date'[Date] >= StartDate
&& 'Date'[Date] <= EndDate
)
| Value1 | Value2 |
|---|---|
| 19,143.33 | 386.51 |
-- This example shows the sales in the current month
-- along with the sales in the first and last day of the month.
DEFINE
MEASURE Sales[Sales first day] =
CALCULATE (
[Sales Amount],
FIRSTDATE ( 'Date'[Date] )
)
MEASURE Sales[Sales last day] =
CALCULATE (
[Sales Amount],
LASTDATE ( 'Date'[Date] )
)
EVALUATE
SUMMARIZECOLUMNS (
'Date'[Calendar Year Month Number],
"Sales Amount", [Sales Amount],
"Sales first day", [Sales first day],
"Sales last day", [Sales last day]
)
ORDER BY [Calendar Year Month Number]
| Calendar Year Month Number | Sales Amount | Sales first day | Sales last day |
|---|---|---|---|
| 200701 | 794,248.24 | (Blank) | 9,679.45 |
| 200702 | 891,135.91 | 29,563.13 | 2,626.20 |
| … | … | … | … |
| 200911 | 868,164.01 | 951.05 | 887.11 |
| 200912 | 746,933.50 | 18,046.77 | 40,930.59 |
Related articles
Learn more about LASTDATE in the following articles:
-
Semi-Additive Measures in DAX
Values such as inventory and balance account, usually calculated from a snapshot table, require the use of semi-additive measures. In Multidimensional you have specific aggregation types, like LastChild and LastNonEmpty. In PowerPivot and Tabular you use DAX, which is flexible enough to implement any calculation, as described in this article. » Read more
-
Understanding the difference between LASTDATE and MAX in DAX
This article explains why in many cases, MAX should be used instead of LASTDATE to search for the last date in a time period using DAX. » Read more
-
Differences between DATEADD and PARALLELPERIOD in DAX
This article describes the difference between the results of DATEADD and PARALLELPERIOD in DAX. These differences also impact many other time intelligence functions that are syntax sugar of these two. » Read more
Related functions
Other related functions are:
Last update: Nov 14, 2024 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo
Microsoft documentation: https://docs.microsoft.com/en-us/dax/lastdate-function-dax