--  ISINSCOPE is useful to detect if a column is currently
--  in the rows or columns of a visual (like groupby columns 
--  of SUMMARIZECOLUMNS) AND it has only one value visible
EVALUATE
TOPN (
   20,
    SUMMARIZECOLUMNS (
        'Product'[Brand],
        Customer[CountryRegion],
        "Brand in scope", ISINSCOPE ( 'Product'[Brand] ),
        "Country in scope", ISINSCOPE ( Customer[CountryRegion] ),
        "Product name in scope", ISINSCOPE ( 'Product'[Product Name] )
    )
)

--  In this example we use ISINSCOPE to compute the percentage
--  over the parent level in a hierarchy over products
DEFINE
    MEASURE Sales[Pct over parent] =
        VAR AllSales =
            CALCULATE ( [Sales Amount], ALLSELECTED () )
        VAR CategorySales =
            CALCULATE ( [Sales Amount], ALLSELECTED (), VALUES ( Product[Category] ) )
        VAR CurrentSales = [Sales Amount]
        RETURN
            SWITCH (
                TRUE (),
                ISINSCOPE ( 'Product'[Subcategory] ), DIVIDE ( CurrentSales, CategorySales ),
                ISINSCOPE ( 'Product'[Category] ),    DIVIDE ( CurrentSales, AllSales )
            )
EVALUATE
CALCULATETABLE (
    SUMMARIZECOLUMNS (
        'Product'[Category],
        ROLLUPADDISSUBTOTAL ( 'Product'[Subcategory], "Category total" ),
        "Sales Amount", [Sales Amount],
        "Pct over parent", [Pct over parent]
    ),
    'Product'[Category] IN { "Audio", "TV and Video" }
)
ORDER BY
    Product[Category],
    [Category Total],
    Product[Subcategory]

--  ISINSCOPE, like ALLSELECTED, deduces the information about
--  the grouping of a column from a different algorithm:
--  the column must show only one value in the filter context
--  and the filter must be coming from either a groupby column 
--  introduced by SUMMARIZECOLUMNS, or from a context transition.
--  Besides, the filter must be still active (not overridden)
EVALUATE
ADDCOLUMNS (
    VALUES ( 'Product'[Color] ),
    "ISINSCOPE 1",
	    CALCULATE ( 
	        INT ( ISINSCOPE ( 'Product'[Color] ) ),
	        FILTER ( VALUES ( Product[Color] ), TRUE )
	    ),
    "ISINSCOPE 2",
	    CALCULATE ( 
	        INT ( ISINSCOPE ( 'Product'[Color] ) ),
	        KEEPFILTERS ( FILTER ( VALUES ( Product[Color] ), TRUE ) )
	    )
)