FILTERS DAX Function (Table manipulation)
Returns a table of the filter values applied directly to the specified column.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
| ColumnName |
The column for which filter values are to be returned. |
Return values
The values filtered directly on ColumnName, or all the values of the column when there is no direct filter.
Remarks
When FILTERS is evaluated in an expression grouped in SUMMARIZECOLUMNS the original filter could be lost and replaced by the result of the auto-exists behavior that combines all the filters on the same table into a single filter. The combined table resulting from this filter only contains columns explicitly listed in SUMMARIZECOLUMNS as grouping columns or filter columns.
FILTERS can have an additional blank row in case the table has at least one one-to-many relationship with other tables where there is a violation of referential integrity.
FILTERS returns only the values that are filtered directly on ColumnName. A filter on other columns only, of the same table or of other tables, does not change the result of FILTERS, also when it hides some values of ColumnName. VALUES returns only the values that are visible after all the filters. When ColumnName has no direct filter, FILTERS returns all the values of the column. A value in the filter that does not exist in the column is not in the result.
ColumnName must be a column reference. If the argument is an expression, FILTERS returns an error.
This function is not supported in DirectQuery mode when used in calculated columns or row-level security (RLS) rules.
» 6 related functions
Examples
-- FILTERS returns the filters directly applied to a column
EVALUATE
CALCULATETABLE (
FILTERS ( 'Product'[Category] ),
'Product'[Category] = "Audio"
)
EVALUATE
CALCULATETABLE (
FILTERS ( 'Product'[Category] ),
'Product'[Category] IN { "Audio", "Computers" }
)
| Category |
|---|
| Audio |
| Category |
|---|
| Audio |
| Computers |
-- Non-existing values are not considered as filters
-- The "Bananas" category does not exist in Product table
EVALUATE
CALCULATETABLE (
FILTERS ( 'Product'[Category] ),
'Product'[Category] IN { "Audio", "Bananas" }
)
| Category |
|---|
| Audio |
-- Filter on one column does not affect other columns,
-- which are cross-filtered but not filtered.
-- Only "Cameras and camcorders" has products with Azure color.
EVALUATE
CALCULATETABLE (
FILTERS ( 'Product'[Category] ),
'Product'[Color] = "Azure"
)
EVALUATE
CALCULATETABLE (
VALUES ( 'Product'[Category] ),
'Product'[Color] = "Azure"
)
-- Table filter include columns used in FILTERS
EVALUATE
CALCULATETABLE (
FILTERS ( 'Product'[Category] ),
FILTER ( 'Product', 'Product'[Color] = "Azure" )
)
| Category |
|---|
| Audio |
| TV and Video |
| Computers |
| Cameras and camcorders |
| Cell phones |
| Music, Movies and Audio Books |
| Games and Toys |
| Home Appliances |
| Category |
|---|
| Cameras and camcorders |
| Category |
|---|
| Cameras and camcorders |
-- FILTERS returns its values even though there are no
-- rows satisfying the set of conditions.
-- The table returned by FILTERS has the correct lineage.
EVALUATE
CALCULATETABLE (
ADDCOLUMNS (
FILTERS ( 'Product'[Color] ),
"#Prods", CALCULATE ( COUNTROWS ( 'Product' ) )
),
'Product'[Color] IN { "White", "Azure" },
'Product'[Brand] = "Litware"
)
| Color | #Prods |
|---|---|
| White | 45 |
| Azure | (Blank) |
-- FILTERS returns the values filtered directly on the column.
-- VALUES returns only the values that are visible after all the filters.
-- Litware has no Azure products: VALUES returns only White, whereas
-- FILTERS returns both colors. For the same reason, HASONEFILTER
-- returns FALSE and HASONEVALUE returns TRUE.
EVALUATE
CALCULATETABLE (
ROW (
"FILTERS", CONCATENATEX ( FILTERS ( 'Product'[Color] ), 'Product'[Color], ", ", 'Product'[Color] ),
"VALUES", CONCATENATEX ( VALUES ( 'Product'[Color] ), 'Product'[Color], ", ", 'Product'[Color] ),
"HASONEFILTER", HASONEFILTER ( 'Product'[Color] ),
"HASONEVALUE", HASONEVALUE ( 'Product'[Color] )
),
'Product'[Color] IN { "White", "Azure" },
'Product'[Brand] = "Litware"
)
| FILTERS | VALUES | HASONEFILTER | HASONEVALUE |
|---|---|---|---|
| Azure, White | White | False | True |
Related articles
Learn more about FILTERS in the following articles:
-
Displaying filter context in Power BI Tooltips
This article describes how to display the filter context applied to a calculation using a special DAX measure in Power BI Tooltips. » Read more
Related functions
Other related functions are:
Last update: Nov 19, 2026 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo
Microsoft documentation: https://learn.microsoft.com/en-us/dax/filters-function-dax