--  EXPAND moves the visual calculation down the ROWS axis.
--  The query simulates a matrix with Year, Quarter, and Month on rows.
--  Expression must aggregate the values of the lower level.
--  MaxOfChildren:      largest value one level down (N = 1 is the default)
--  MaxOfGrandchildren: largest value two levels down
--  MaxMonth:           largest value at the Month level (no move on Month)
--  AvgOfChildren:      EXPAND without expression, as a CALCULATE modifier
DEFINE
    COLUMN '__V'[MaxOfChildren] = EXPAND ( MAX ( [Sales Amount] ), ROWS )
    COLUMN '__V'[MaxOfGrandchildren] = EXPAND ( MAX ( [Sales Amount] ), ROWS, 2 )
    COLUMN '__V'[MaxMonth] = EXPAND ( MAX ( [Sales Amount] ), [Month] )
    COLUMN '__V'[AvgOfChildren] =
        CALCULATE ( AVERAGE ( [Sales Amount] ), EXPAND ( ROWS ) )
    VAR __Core =
        SUMMARIZECOLUMNS (
            ROLLUPADDISSUBTOTAL (
                'Date'[Calendar Year Number], "IsGrandTotalRowTotal",
                'Date'[Calendar Year Quarter Number], "IsYearTotal",
                'Date'[Calendar Year Month Number], "IsQuarterTotal"
            ),
            TREATAS ( { 2007, 2008 }, 'Date'[Calendar Year Number] ),
            TREATAS ( { 1, 2, 3, 4, 5, 6 }, 'Date'[Month Number] ),
            "Sales_Amount", [Sales Amount]
        )
    VAR __Input =
        SELECTCOLUMNS (
            __Core,
            "Year", 'Date'[Calendar Year Number],
            "Quarter", 'Date'[Calendar Year Quarter Number],
            "Month", 'Date'[Calendar Year Month Number],
            "IsGrandTotalRowTotal", [IsGrandTotalRowTotal],
            "IsYearTotal", [IsYearTotal],
            "IsQuarterTotal", [IsQuarterTotal],
            "Sales Amount", [Sales_Amount]
        )
    TABLE '__V' = __Input
        WITH VISUAL SHAPE
        AXIS ROWS
            GROUP [Year] TOTAL [IsGrandTotalRowTotal]
            GROUP [Quarter] TOTAL [IsYearTotal]
            GROUP [Month] TOTAL [IsQuarterTotal]
            ORDER BY [Year] ASC, [Quarter] ASC, [Month] ASC
        DENSIFY "IsDensifiedRow"
EVALUATE
SELECTCOLUMNS (
    '__V',
    "Year", [Year],
    "Quarter", [Quarter],
    "Month", [Month],
    "Sales Amount", [Sales Amount],
    "MaxOfChildren", [MaxOfChildren],
    "MaxOfGrandchildren", [MaxOfGrandchildren],
    "MaxMonth", [MaxMonth],
    "AvgOfChildren", [AvgOfChildren]
)
ORDER BY [Year], [Quarter], [Month]