ENDOFMONTH DAX Function (Time Intelligence) Context Transition
Returns the end of month.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
| Dates |
The name of a column containing dates, a single column table containing dates, or a calendar reference. |
Return values
For a date column, a table containing a single column and a single row with a date value. For a calendar, a table with a single row that contains the primary column of each calendar category and the time-related columns of the calendar.
Notes
In order to use any time intelligence calculation, you need a well-formed date table. The Date table must satisfy the following requirements:
- All dates need to be present for the years required. The Date table must always start on January 1 and end on December 31, including all the days in this range. If the report only references fiscal years, then the date table must include all the dates from the first to the last day of a fiscal year. For example, if the fiscal year 2008 starts on July 1, 2007, then the Date table must include all the days from July 1, 2007 to June 30, 2008.
- There needs to be a column with a DateTime or Date data type containing unique values. This column is usually called Date. Even though the Date column is often used to define relationships with other tables, this is not required. Still, the Date column must contain unique values and should be referenced by the Mark as Date Table feature. In case the column also contains a time part, no time should be used – for example, the time should always be 12:00 am.
- The Date table must be marked as a date table in the model, in case the relationship between the Date table and any other table is not based on the Date.
Remarks
The <Dates> argument can be any of the following:
- A reference to a date/time column. In this case, a context transition applies because the column reference is replaced by
- CALCULATETABLE ( DISTINCT ( <Dates> ) )
- A table expression that returns a single column of date/time values.
- A Boolean expression that defines a single-column table of date/time values (when used in a CALCULATE filter argument).
- A calendar reference. You define a calendar in the model for calendar-based time intelligence. With a calendar, the result has the primary column of each calendar category and the time-related columns of the calendar. Also in this case, a context transition applies.
ENDOFMONTH filters <Dates> into a 1-row, 1-column table that shows only the latest date, in the entire <Dates> column devoid of all filters, that is in the same year and month as the latest visible date in <Dates>.
With a date column, the following ENDOFMONTH call
ENDOFMONTH ( 'Date'[date] )
is a more efficient implementation of the following semantically equivalent expression:
VAR LastDateVisible =
CALCULATE ( MAX ( 'Date'[Date] ) )
VAR LastYearVisible =
YEAR ( LastDateVisible )
VAR LastMonthVisible =
MONTH ( LastDateVisible )
VAR DaysInMonth =
FILTER (
ALL ( 'Date'[Date] ),
YEAR ( 'Date'[Date] ) = LastYearVisible
&& MONTH ( 'Date'[Date] ) = LastMonthVisible
)
VAR LastDayInMonth =
MAXX (
DaysInMonth,
'Date'[Date]
)
VAR Result =
CALCULATETABLE (
VALUES ( 'Date'[Date] ),
'Date'[Date] = LastDayInMonth
)
RETURN
Result
With a calendar, ENDOFMONTH uses the months that the calendar defines. For example, a month of the Weekly 445 calendar is a period of 4 or 5 weeks, from Sunday to Saturday. ENDOFMONTH finds the last date visible in the filter context and returns the last day of the month that includes this date. The result can be a date that the filter context hides. For example, with a filter on the Date column from August 1 to August 13, 2008, ENDOFMONTH ( Gregorian ) returns August 31, 2008, and ENDOFMONTH ( ‘Weekly 445’ ) returns August 23, 2008, the last day of period P08-2008.
With a calendar, CALCULATE removes only the filters on the columns of the calendar. The filters on the other columns of the date table stay, for example a filter on the day of the week. With the date column of a table marked as a date table, CALCULATE removes all the filters on the date table.
Do not use ENDOFMONTH in visual calculations. The result is likely to have no meaning.
This function is not supported in DirectQuery mode when used in calculated columns or row-level security (RLS) rules.
» 3 related functions
Examples
-- If the selection is a single date, the result is a table with
-- the requested date.
EVALUATE
CALCULATETABLE (
STARTOFMONTH ( 'Date'[Date] ),
'Date'[Date] = DATE ( 2007, 5, 12 )
)
EVALUATE
CALCULATETABLE (
ENDOFMONTH ( 'Date'[Date] ),
'Date'[Date] = DATE ( 2007, 5, 12 )
)
| Date |
|---|
| 2007-05-01 |
| Date |
|---|
| 2007-05-31 |
-- If the selection contains larger periods, it returns the beginning or
-- the end of the entire period.
-- The result is always a single-row table.
EVALUATE
CALCULATETABLE (
STARTOFMONTH ( 'Date'[Date] ),
'Date'[Date] >= DATE ( 2007, 2, 5 ) &&
'Date'[Date] <= DATE ( 2007, 5, 12 )
)
EVALUATE
CALCULATETABLE (
ENDOFMONTH ( 'Date'[Date] ),
'Date'[Date] >= DATE ( 2007, 2, 5 ) &&
'Date'[Date] <= DATE ( 2007, 5, 12 )
)
| Date |
|---|
| 2007-02-01 |
| Date |
|---|
| 2007-05-31 |
-- All time intelligence functions are designed to return a table
-- to be easily used in CALCULATE as a filter.
EVALUATE
{
CALCULATE (
CALCULATE (
[Sales Amount],
ENDOFMONTH ( 'Date'[Date] ) -- 2007-05-31
),
'Date'[Date] = DATE ( 2007, 5, 12 )
)
}
| Value |
|---|
| 6,593.04 |
-- With a calendar, ENDOFMONTH uses the months of that calendar.
-- Gregorian and Weekly 445 are calendars defined on the Date table.
-- In Weekly 445, a month is a period of 4 or 5 weeks from Sunday to Saturday.
-- Period P08-2008 ends on August 23, 2008.
-- The result has the primary column of each calendar category
-- and the time-related columns of the calendar.
EVALUATE
CALCULATETABLE (
ENDOFMONTH ( Gregorian ),
'Date'[Date] = DATE ( 2008, 8, 13 )
)
EVALUATE
CALCULATETABLE (
ENDOFMONTH ( 'Weekly 445' ),
'Date'[Date] = DATE ( 2008, 8, 13 )
)
| Date | Month Number | Calendar Year Month Number | Calendar Year Quarter Number | Calendar Year Number |
|---|---|---|---|---|
| 2008-08-31 | 8 | 200808 | 20083 | 2008 |
| Date | 445 Week Number | 445 Year Week Number | 445 Period Number | 445 Year Period Number | 445 Quarter Number | 445 Year Quarter Number | 445 Year Number |
|---|---|---|---|---|---|---|---|
| 2008-08-23 | 34 | 200834 | 8 | 200808 | 3 | 20083 | 2008 |
Related articles
Learn more about ENDOFMONTH in the following articles:
-
Semi-Additive Measures in DAX
Values such as inventory and account balance, usually calculated from a snapshot table, require the use of semi-additive measures. This article describes how to implement these calculations in DAX according to your specific requirements. » Read more
Related functions
Other related functions are:
Last update: Nov 16, 2026 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo
Microsoft documentation: https://learn.microsoft.com/en-us/dax/endofmonth-function-dax