--  CONTAINSROW requires to specify one value  
--  for each column of the lookup table.
DEFINE MEASURE Sales[Customers without stores] = 
    COUNTROWS (
        FILTER (
            Customer,
            NOT CONTAINSROW (
                SUMMARIZE ( Store, Store[CountryRegion], Store[City] ),
                Customer[CountryRegion],
                Customer[City]
            )
        )
    )
EVALUATE
SUMMARIZECOLUMNS (
    Customer[CountryRegion],
    "Customers", COUNTROWS ( Customer ),
    "Customers without stores", [Customers without stores]
)

--  Internally, the IN operator invokes a corresponding
--  CONTAINSROW filter.
--  The CONTAINSROW function has as many arguments after the
--  first one as the number of column in each row of the table
--  passed in the first argument. Only IN uses the tuples syntax
EVALUATE
{
     ( 1, "IN", COUNTROWS (
        FILTER (
            Customer,
             ( Customer[City], Customer[State] )
                IN { ( "New York", "New York" ), ( "Columbus", "Ohio" ) }
        )
    ) ),
     ( 2, "CONTAINSROW", COUNTROWS (
        FILTER (
            Customer,
            CONTAINSROW (
                { ( "New York", "New York" ), ( "Columbus", "Ohio" ) },
                Customer[City],
                Customer[State]
            )
        )
    ) )
}