--  EXPANDALL moves the visual calculation to the lowest level of the axis.
--  The query simulates a matrix with Year, Quarter, and Month on rows.
--  Expression must aggregate the values of the lowest level.
--  EXPANDALL returns the largest month of the current cell on every row.
--  EXPAND moves down only one level.
--  Min Month uses EXPANDALL without expression, as a CALCULATE modifier
DEFINE
    COLUMN '__V'[ExpandAll] = EXPANDALL ( MAX ( [Sales Amount] ), ROWS )
    COLUMN '__V'[Expand] = EXPAND ( MAX ( [Sales Amount] ), ROWS )
    COLUMN '__V'[MinMonth] =
        CALCULATE ( MIN ( [Sales Amount] ), EXPANDALL ( ROWS ) )
    VAR __Core =
        SUMMARIZECOLUMNS (
            ROLLUPADDISSUBTOTAL (
                'Date'[Calendar Year Number], "IsGrandTotalRowTotal",
                'Date'[Calendar Year Quarter Number], "IsYearTotal",
                'Date'[Calendar Year Month Number], "IsQuarterTotal"
            ),
            TREATAS ( { 2007, 2008 }, 'Date'[Calendar Year Number] ),
            TREATAS ( { 1, 2, 3, 4, 5, 6 }, 'Date'[Month Number] ),
            "Sales_Amount", [Sales Amount]
        )
    VAR __Input =
        SELECTCOLUMNS (
            __Core,
            "Year", 'Date'[Calendar Year Number],
            "Quarter", 'Date'[Calendar Year Quarter Number],
            "Month", 'Date'[Calendar Year Month Number],
            "IsGrandTotalRowTotal", [IsGrandTotalRowTotal],
            "IsYearTotal", [IsYearTotal],
            "IsQuarterTotal", [IsQuarterTotal],
            "Sales Amount", [Sales_Amount]
        )
    TABLE '__V' = __Input
        WITH VISUAL SHAPE
        AXIS ROWS
            GROUP [Year] TOTAL [IsGrandTotalRowTotal]
            GROUP [Quarter] TOTAL [IsYearTotal]
            GROUP [Month] TOTAL [IsQuarterTotal]
            ORDER BY [Year] ASC, [Quarter] ASC, [Month] ASC
        DENSIFY "IsDensifiedRow"
EVALUATE
SELECTCOLUMNS (
    '__V',
    "Year", [Year],
    "Quarter", [Quarter],
    "Month", [Month],
    "Sales Amount", [Sales Amount],
    "EXPANDALL", [ExpandAll],
    "EXPAND", [Expand],
    "Min Month", [MinMonth]
)
ORDER BY [Year], [Quarter], [Month]