STARTOFQUARTER DAX Function (Time Intelligence) Context Transition
Returns the start of quarter.
Syntax
| Parameter | Attributes | Description |
|---|---|---|
| Dates |
The name of a column containing dates or a one column table containing dates. |
Return values
A table containing a single column and single row with a date value.
Notes
In order to use any time intelligence calculation, you need a well-formed date table. The Date table must satisfy the following requirements:
- All dates need to be present for the years required. The Date table must always start on January 1 and end on December 31, including all the days in this range. If the report only references fiscal years, then the date table must include all the dates from the first to the last day of a fiscal year. For example, if the fiscal year 2008 starts on July 1, 2007, then the Date table must include all the days from July 1, 2007 to June 30, 2008.
- There needs to be a column with a DateTime or Date data type containing unique values. This column is usually called Date. Even though the Date column is often used to define relationships with other tables, this is not required. Still, the Date column must contain unique values and should be referenced by the Mark as Date Table feature. In case the column also contains a time part, no time should be used – for example, the time should always be 12:00 am.
- The Date table must be marked as a date table in the model, in case the relationship between the Date table and any other table is not based on the Date.
Remarks
The <Dates> argument can be any of the following:
- A reference to a date/time column. Only in this case a context transition applies because the column reference is replaced by
- CALCULATETABLE ( DISTINCT ( <Dates> ) )
- A table expression that returns a single column of date/time values.
- A Boolean expression that defines a single-column table of date/time values.
STARTOFQUARTER filters <Dates> into a 1-row, 1-column table that shows only the earliest date, in the entire <Dates> column devoid of all filters, that is in the same year and quarter as the earliest visible date in <Dates>.
The following STARTOFQUARTER call
STARTOFQUARTER ( 'Date'[date] )
is a more efficient implementation of the following semantically equivalent expression:
VAR FirstDateVisible =
CALCULATE ( MIN ( 'Date'[Date] ) )
VAR FirstYearVisible =
YEAR ( FirstDateVisible )
VAR FirstQuarterVisible =
QUOTIENT ( MONTH ( FirstDateVisible ) - 1, 3 )
VAR DaysInQuarter =
FILTER (
ALL ( 'Date'[Date] ),
YEAR ( 'Date'[Date] ) = FirstYearVisible
&& QUOTIENT ( MONTH ( 'Date'[Date] ) - 1, 3 ) = FirstQuarterVisible
)
VAR FirstDayInQuarter =
MINX (
DaysInQuarter,
'Date'[Date]
)
VAR Result =
CALCULATETABLE (
VALUES ( 'Date'[Date] ),
'Date'[Date] = FirstDayInQuarter
)
RETURN
Result
» 5 related functions
Examples
-- If the selection is a single date, the result is a table with
-- the requested date.
EVALUATE
CALCULATETABLE (
STARTOFQUARTER ( 'Date'[Date] ),
'Date'[Date] = DATE ( 2007, 5, 12 )
)
EVALUATE
CALCULATETABLE (
ENDOFQUARTER ( 'Date'[Date] ),
'Date'[Date] = DATE ( 2007, 5, 12 )
)
| Date |
|---|
| 2007-04-01 |
| Date |
|---|
| 2007-06-30 |
-- If the selection contains larger periods, it returns the beginning or
-- the end of the entire period.
-- The result is always a single-row table.
EVALUATE
CALCULATETABLE (
STARTOFQUARTER ( 'Date'[Date] ),
'Date'[Date] >= DATE ( 2007, 2, 5 ) &&
'Date'[Date] <= DATE ( 2007, 5, 12 )
)
EVALUATE
CALCULATETABLE (
ENDOFQUARTER ( 'Date'[Date] ),
'Date'[Date] >= DATE ( 2007, 2, 5 ) &&
'Date'[Date] <= DATE ( 2007, 5, 12 )
)
| Date |
|---|
| 2007-01-01 |
| Date |
|---|
| 2007-06-30 |
-- All time intelligence function are designed to return a table
-- to be easily used in CALCULATE as a filter.
EVALUATE
{
CALCULATE (
CALCULATE (
[Sales Amount],
STARTOFQUARTER ( 'Date'[Date] ) -- 2007-04-01
),
'Date'[Date] = DATE ( 2007, 5, 12 )
)
}
| Value |
|---|
| 99,216.59 |
Related articles
Learn more about STARTOFQUARTER in the following articles:
-
Semi-Additive Measures in DAX
Values such as inventory and account balance, usually calculated from a snapshot table, require the use of semi-additive measures. This article describes how to implement these calculations in DAX according to your specific requirements. » Read more
Related functions
Other related functions are:
Last update: Nov 14, 2024 » Contribute » Show contributors
Contributors: Alberto Ferrari, Marco Russo
Microsoft documentation: https://docs.microsoft.com/en-us/dax/startofquarter-function-dax